home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 005 / budget.arc / BESTLINE.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1985-06-26  |  896 b   |  44 lines
  1. 240  CLS
  2. 250  PRINT TAB(30)"LINEAR REGRESSION":PRINT :PRINT
  3. 260  INPUT "NUMBER OF KNOWN POINTS";N
  4. 270  J=0
  5. 280  K=0
  6. 290  L=0
  7. 300  M=0
  8. 310  R2=0
  9. 320  REM LOOP TO ENTER COORDINATES OF POINTS
  10. 330  FOR I=1 TO N
  11. 340  PRINT "X,Y OF POINT ";I;
  12. 350  INPUT X,Y
  13. 360  REM ACCUMULAT INTERMEDIATE SUMS
  14. 370  J=J+X
  15. 380  K=K+Y
  16. 390  L=L+X^2
  17. 400  M=M+Y^2
  18. 410  R2=R2+X*Y
  19. 420  NEXT I
  20. 430  B=(N*R2-K*J)/(N*L-J^2)
  21. 440  A=(K-B*J)/N
  22. 450  PRINT
  23. 460  PRINT "F(X)=";A;"+(";B;"*X)"
  24. 470  REM COMPUTE REGRESSION ANALYSIS
  25. 480  J=B*(R2-J*K/N)
  26. 490  M=M-K^2/N
  27. 500  K=M-J
  28. 510  PRINT
  29. 520  R2=J/M
  30. 530  PRINT "COEFFICIENT OF DETERMINATION (R^2)=";R2
  31. 540  PRINT "COEFFICIENT OF CORRELATION= ";SQR(R2)
  32. 550  PRINT "STANDARD ERROR OF ESTIMATE=";SQR(K/(N-2))
  33. 560  PRINT
  34. 570  REM ESTIMATE Y-COORDINATES OF POINTS WITH ENTERED X-COORDINATES
  35. 580  PRINT "INTERPOLATION:(ENTER X=0 TO END PROGRAM)"
  36. 590  PRINT "X=";
  37. 600  INPUT X
  38. 610  REM RESTART OR END PROGRAM
  39. 620  IF X=0 THEN 660
  40. 630  PRINT "Y=";A+B*X
  41. 640  PRINT
  42. 650  GOTO 590
  43. 660  END
  44.